Cleanup old files depending on the age of x days, folder and file extension

'********************************************************************************
' name:     Cleanup.vbs
' function: Cleanup old files depending on the age of X days, folder and file ext
' options:  /dir:*  /days:* /? (*=requiered)
' author:   Pinkel
' version:  1.1
' date:     01-04-2011
' correction date: 03-11-2011
' correction author: superurbi
'********************************************************************************
Option Explicit
Dim wshArgs, wshShell
Dim FilePath, Retention, FileFilter, FilterExt
Dim fso, writelog, Folder, xFileDelete, xErrorDelete
Set wshArgs = wscript.arguments
Set wshShell = wscript.createobject("wscript.shell")
Set fso = CreateObject("Scripting.FileSystemObject")
If ChkArgs = True then
	FilePath = wshArgs.named.item("dir")
	Retention = wshArgs.named.item("days")
	FilterExt = wshArgs.named.item("ext")
	Set writelog = fso.OpenTextFile( FilePath & "\" & GetLogName(), 8, True)
	writelog.writeline "Operation cleanup started in " & FilePath & " on " & Date & ", at " & Time & "."
	writelog.writeline "Cleaning files from " & FilePath & " older then " & Retention & " days."
	DelFiles FilePath, Retention, FileFilter
	writelog.writeline "Operation cleunup finished in " & FilePath & " on " & Date & ", at " & Time & "."
Else
	ShowUsage 1
	wshShell.LogEvent 2, "Operation cleanup failed (Cleanup.VBS). Requiered options are missing."
	wscript.echo "Operation cleanup FAILED!"
	wscript.echo "Requiered options are missing."
End If
Set wshArgs = Nothing
Set wshShell = Nothing
Set fso = Nothing
FilePath = ""
Retention = ""
Function ChkArgs
	Dim PathArg, DaysArg, ExtArg, HelpArg
	PathArg = wshArgs.Named.exists("dir")
	DaysArg = wshArgs.named.exists("days")
	ExtArg = wshArgs.named.exists("ext")
	HelpArg = wshArgs.named.exists("?")
	If HelpArg = True then
		ShowUsage 0
		wscript.quit
	End If
	If PathArg = True and DaysArg = True then 
		ChkArgs = True
	Else
		ChkArgs = False
	End If
	If ExtArg = True then
		FileFilter = True
	Else
		FileFilter = False
	End If
End Function
Function GetLogName
	GetLogName = Year(Now()) & Month(Now()) & Day(Now()) & "-optuim.log"
End Function
Sub ShowUsage(Mode)
	wscript.echo "CLEANUP.VBS ussage:" & _
	vbcrlf & _
	vbcrlf & _
	" Cleanup.vbs /dir:[path] /days:[older than x days] /ext:[file extension]" & _
	vbcrlf & _
	"path = Folder location of the files." & _
	vbcrlf & _
	"older then x days = Required life time of files, older files will be deleted." & _
	vbcrlf & _
	"file extension = option: Cleaning files with an exention (only the extension, no dot)" & _
	vbcrlf & _
	"All files older than x days, will be deleted." 
	If Mode = 0 then
		wscript.quit
	Else
	End If
End Sub
Sub DelFiles(Dir, days, DelFilter)
	Dim DelDate, FSO, Folder, SubFolder, SubDir, Files, File, FileDate, Ext, FileDelete, ErrorDelete
	Set FSO = createobject("scripting.filesystemobject")
	On Error Resume Next
	Set Folder = FSO.GetFolder(Dir)
	If Err.Number = 76 then
		wscript.echo "Operation cleanup FAILED! - Folder not found."
		wshShell.LogEvent 2, "Operation cleanup FAILED! (Cleanup.VBS) - Folder not found."
		wscript.quit
	End If
	ErrorDelete = 0
	FileDelete = 0
	DelDate = Now - days
	On Error Goto 0
	Set Files = Folder.Files
	Set SubFolder = Folder.SubFolders
	For each File in Files
		FileDate = File.DateLastModified
		Ext = FSO.GetExtensionName(File)
		On Error Resume Next
		If DelFilter = True then
			If FileDate <= DelDate and Ext = FilterExt then
				File.Delete
				FileDelete = FileDelete + 1
			End If
			Else
			If FileDate <= DelDate then
				File.Delete
				FileDelete = FileDelete + 1
			End If
		End If
		If Err.Number = 70 Then
			wscript.echo "File " & Dir & "\" & File.Name & _
			" not deleted: Failed - ACCESS DENIED!"
			wshShell.LogEvent 2, "File " & Dir & "\" & _
			File.Name & " not deleted: Failed - ACCESS DENIED! (Cleanup.VBS)"
			writelog.writeline "File " & Dir & "\" & File.Name
			writelog.writeline " not deleted: Failed - ACCESS DENIED!" & Time
			ErrorDelete = ErrorDelete + 1
		End If
		On Error Goto 0
	Next
	
	For each SubDir in SubFolder
		DelFiles SubDir.Path, days, DelFilter
	Next
	
	writelog.writeline FileDelete & " files deleted from folder " & Dir & "."
	writelog.writeline ErrorDelete & " errors found."
	
	Set Files = Nothing
	Set Folder = Nothing
	Set FSO = Nothing
	FileDelete = ""
	ErrorDelete = ""
End Sub